ActiveX コントロール

ActiveX API は Linux と Windows の両方用に提供されています。しかし、Linux では ActiveX コントロールが無いため、実行時に ActiveXException がスローされる可能性があります。この Linux でスローされる例外は、Windows 上でActiveXコントロールがインストールされていない状況で、アプレットがその実存しないコントロールにアクセスしようとする時にスローされる例外と一致しています。

ActiveX コントロールを Curl アプレットに追加する

ActiveX コントロールのインスタンスを作成し、そのインスタンスのメソッドとフィールドを使用するためには、Curl® 言語の ActiveXObject クラスを使用します。ActiveXObject クラスはGraphic のサブクラスです。そのため、Curl アプレットに ActiveXObject を挿入することが出来ます。(子オブジェクトをトップに展開する Box に配置されると、ActiveXGraphic は常に他の子オブジェクトのトップに配置されます。これは ActiveXGraphic が新規のホストウィンドウを作成するためです。)

注意: このチャプターで使用されているコード例では、他のチャプターで見られるような例とは違い、ページ上から直に実行することは出来ません。[ ActiveX オブジェクトは特権があるアプレットからのみ生成可能なためです。]

以下にある例を実行するためには、コード例を、空のアプレットのファイルにコピーしてから実行します。そのアプレットは、特権付きロケーションに保存されている必要があります。特権を与えるには、Curl コントロールパネルを使用してください。特権に関しての詳しい内容は開発者ガイドの「特権付アプレット」を参照してください。

以下の例では、Microsoft®のカレンダーコントロールを作成し、Frame に挿入します。 ActiveXObject のファクトリの引数として、Program ID　または　Class ID を挿入します。 ActiveX オブジェクトの program ID と Class ID は、そのオブジェクトのドキュメンテーションから引用・コピーすることが出来ます。 Program ID は、引用符の中に入れる必要があります。 Class ID は、逐語的文字列として使用します。逐語的文字列の詳しい内容は、開発者ガイドの「逐語的文字列」を参照してください。

コード例

{import * from CURL.GRAPHICS.ACTIVEX}

|| ActiveX カレンダー コントロール
{let xobj:ActiveXObject =
    {ActiveXObject
||        program id を使用
||        ProgId = "mscal.calendar"
||        class id を使用
        ClsId = |"{8E27C92B-1264-101C-8A2F-040224009C02}"|
    }
}

{value
    {Frame
        border-color = "black",
        border-width = 2px,
        margin = 2px,
        background = "blue",
        {ActiveXGraphic
            width = 8cm,
            height = 8cm,
            xobj
        }
    }
}
{do
    {set xobj.Year = 1998}
}

ActiveX コントロールのメソッドを参照する

コード例

{applet
    {compiler-directives
        stringent? =  true
    }
}
{import * from CURL.GRAPHICS.ACTIVEX}
{import ActiveXGraphic from CURL.GUI.BASE}

{let activex-object:ActiveXObject =
    {ActiveXObject
        ProgId = "mscal.calendar"
    }
}
{let method-info-graphic:VBox = {VBox}}
{let num-methods:int = activex-object.method-count}
{do
    {method-info-graphic.add {HBox {bold Methods}}}
    {method-info-graphic.add
        {HBox "Number of methods: ", num-methods}
    }
    {for i:int = 0 below num-methods do
        let method-info:ActiveXMethodInfo = {activex-object.get-method-info i}
        {method-info-graphic.add
            {HBox "Name: ", method-info.name}
        }
        {if-non-null description = method-info.description then
            {method-info-graphic.add
                {TextFlowBox "Description: ", {value method-info.description}}}
        }

        {method-info-graphic.add
            {HBox "Num args: ", method-info.arg-count}
        }
        {for i:int = 0 below method-info.arg-count do
            {let thistype:ActiveXArgInfo = {method-info.arg-type i}}
            {method-info-graphic.add
                {format "Arg %d: %s", i, thistype.type}
            }

        }
        {method-info-graphic.add {hrule}}
    }
    {method-info-graphic.add {HBox {bold Setters}}}

    let num-setters:int = activex-object.setter-count
    {method-info-graphic.add
        {HBox "Number of setters: ", num-setters}
    }

    {for i:int = 0 below num-setters do
        let setter-info:ActiveXFieldInfo = {activex-object.get-setter-info i}
        {method-info-graphic.add
            {HBox "Setter Name: ", setter-info.name}
        }
        {if-non-null description = setter-info.description then
            {method-info-graphic.add {HBox "Description: ", description}}
        }
        {method-info-graphic.add {HBox "Type: ", setter-info.type.type}}
        {method-info-graphic.add {hrule}}
    }
    {method-info-graphic.add {HBox {bold Getters}}}

    let num-getters:int = activex-object.getter-count
    {method-info-graphic.add
        {HBox "Number of getters: ", num-getters}
    }

    {for i:int = 0 below num-getters do
        let getter-info:ActiveXFieldInfo =
            {activex-object.get-getter-info i}
        {method-info-graphic.add
            {HBox "Getter Name: ", getter-info.name}
        }
        {if-non-null description = getter-info.description then
            {method-info-graphic.add
                {HBox "Description: ", description}
            }
        }
        {method-info-graphic.add {HBox "Type: ", getter-info.type.type}}
        {method-info-graphic.add {hrule}}
    }
}
{value
    method-info-graphic
}

ActiveX の型	方向	Curl のデータ型
VT_EMPTY		null
VT_NULL		null
VT_BSTR		StringInterface
VT_BSTR		#String
VT_BOOL		bool
VT_I1		int8
VT_I2		int16
VT_I4		int32
VT_I8		int64
VT_UI1		uint8
VT_UI2		uint16
VT_UI4		uint32
VT_UI4		char
VT_UI8		uint64
VT_INT		int32
VT_UINT		uint32
VT_R4		float
VT_R8		double
VT_DISPATCH		#ActiveXObject
VT_UNKNOWN		#ActiveXObject
VT_DATE		ActiveXDate
VT_CY		ActiveXCurrency
VT_DECIMAL		ActiveXDecimal
VT_ARRAY \| ...		#{FastArray-of ...}
VT_ARRAY \| VT_VARIANT		#{FastArray-of any}
VT_BYREF \| ...		#{Reference-to ...}
VT_BYREF \| VT_VARIANT		#{Reference-to any}
<引数が省略されている場合>		SkipOptionalArg

ActiveX コントロール

イントロダクション

プラットフォームインディペンデントな ActiveX API。