この Shape およびその子のすべてを描画する
説明
このオプションが未設定の場合、現在の DrawOperation は変更されません。これは、子 Shape が、既定で、親と同じ DrawOperation で描画することを意味します。したがって、オプションの既定値 (DrawOperation.mask) は重要ではなく、単に Renderer2d の既定の初期 DrawOperation を反映します。
このオプションはさまざまな透過性効果を有効にするために使用できます。適したレンダラを使用する必要があることに注意してください。DrawOperation.mask および DrawOperation.source だけがすべてのレンダラでサポートされています。Shape の描画に使用するレンダラのタイプは変えることができます。
「ホストでない」レンダラが必要な場合、および support-advanced-draw-operations? が必要な場合に関する詳細は、DrawOperation を参照してください。
例
この例では、さまざまな描画操作の効果を示すため、動いて重なり合う RectangleShape を使用しています。選択した操作は、四角形のすべての形状の親に設定されます。また、このコードがその Canvas の use-host-rendering? プロパティおよび support-advanced-draw-operations? プロパティを、選択した操作に適した値に変更することに注意してください。
| 例: Shape.draw-operation の使用 | |
 | |
{import * from CURL.GUI.SHAPES}
{import * from CURL.LANGUAGE.MATH-CONSTANT}
{let constant random:Random = {Random}}
{let constant frequency:Frequency = 30fps}
{let constant period:Time = 1 / frequency}
{let constant acceleration:Acceleration2d =
{Acceleration2d 0(m/s^2), 0.1(m/s^2)}
}
{let constant group:ShapeGroup =
{ShapeGroup
draw-operation = DrawOperation.source
}
}
{let constant canvas:Canvas =
{Canvas
width = 6cm,
height = 6cm,
background = "black",
group
}
}
{let constant host-rendering-display:CheckButton =
{CheckButton
label = "use-host-rendering?",
enabled? = false,
value = canvas.use-host-rendering?
}
}
{let constant advanced-operations-display:CheckButton =
{CheckButton
label = "support-advanced-draw-operations?",
enabled? = false,
value = canvas.support-advanced-draw-operations?
}
}
{for i = 0 below 5 do
let constant opacity:float = {random.next-float} * 0.5f + 0.25f
{group.add
{RectangleShape
{GRect 7mm, 7mm, 8mm, 8mm},
color =
{Color.from-rgb
(4 - i) / 4,
0.1,
i / 4,
opacity = opacity
},
user-data = 1 / ({random.next-float} * 1s + 3s),
translation = {Distance2d 0m, i * 5cm / 4 + .5cm},
{TextShape
{format "%0.1f", opacity},
color = "white"
}
}
}
}
{let time:Time = 0s}
{let timer-button:CommandButton =
{CommandButton
label = "Start animation!",
{on Action at cb:CommandButton do
{if timer.enabled? then
set timer.enabled? = false
set cb.label = "Start animation!"
else
set timer.repeat = 600
set timer.enabled? = true
set cb.label = "Stop animation!"
}
}
}
}
{let timer:Timer =
{Timer
enabled? = false,
frequency = frequency,
{on TimerEvent at t:Timer do
{if t.repeat == 0 then
set timer-button.label = "Start animation!"
set timer.enabled? = false
}
{inc time, period}
let constant shapes:{Array-of Shape} =
group.shape-children
{for shape in group.shape-children do
let constant f:Frequency =
shape.user-data asa Frequency
let constant (x:Distance, y:Distance) =
{shape.get-origin-in-shape-parent}
{shape.set-translation-in-parent
((0.5 + 0.5 *
{cos time * 2rad * pi * f + pi * 1rad}) *
canvas.actual-width),
y
}
}
}
}
}
{value canvas}
{VBox
host-rendering-display,
advanced-operations-display
}
{value timer-button}
{RadioFrame
{VBox
spacing = 4pt,
{RadioButton radio-value = DrawOperation.source, value = true},
{RadioButton radio-value = DrawOperation.accumulate},
{RadioButton radio-value = DrawOperation.add},
{RadioButton radio-value = DrawOperation.blend},
{RadioButton radio-value = DrawOperation.blend-premultiply},
{RadioButton radio-value = DrawOperation.invert-destination},
{RadioButton radio-value = DrawOperation.invert-source},
{RadioButton radio-value = DrawOperation.mask}
},
{on ValueFinished at rf:RadioFrame do
let constant op:DrawOperation = rf.value asa DrawOperation
set group.draw-operation = op
{if op == DrawOperation.source or
op == DrawOperation.mask
then
set canvas.use-host-rendering? = true
set canvas.support-advanced-draw-operations? = false
else
set canvas.use-host-rendering? = false
set canvas.support-advanced-draw-operations? =
not (op == DrawOperation.source or
op == DrawOperation.mask or
op == DrawOperation.blend)
}
set host-rendering-display.value =
canvas.use-host-rendering?
set advanced-operations-display.value =
canvas.support-advanced-draw-operations?
}
}
|
