注意事項
このクラスは次の形状オプションを使用します。
例
この例には、パラメータを指定して、細い矢印を記述する Path を作成するプロシージャが含まれます。このプロシージャは独自の矢印を実装する場合に役立ちます。
| 例: 細い矢印を作成する PathShape の使用 | |
 | |
{import * from CURL.GUI.SHAPES}
{define-proc package {make-arrow-path
start:Distance2d,
end:Distance2d,
head-width:Distance,
head-length:Distance
}:Path
let constant length:Distance = (start - end).magnitude
{if length == 0m then
{return {Path}}
}
let constant head-unit-vec:Direction2d = (end - start) / length
let constant head-vec:Distance2d = head-unit-vec * head-length
let constant perpendicular-vec:Distance2d =
(head-width * {Direction2d -head-unit-vec.y, head-unit-vec.x})
let constant side-point-right:Distance2d =
end - head-vec + perpendicular-vec
let constant side-point-left:Distance2d =
end - head-vec - perpendicular-vec
let path:Path =
{Path
start,
PathOperation.line-to,
end,
PathOperation.move-to,
side-point-left,
PathOperation.line-to,
end,
PathOperation.line-to,
side-point-right
}
{return path}
}
{let shape:PathShape =
{PathShape
{make-arrow-path
{Distance2d 1cm, 2cm},
{Distance2d 3cm, 4cm},
2.5mm,
5mm
}
}
}
{HBox
"stroke-thickness: ",
{TextField
width = .5in,
value = "0px",
{on ValueFinished at field:TextField do
set shape.stroke-thickness = {evaluate field.value}
}
}
}
{value shape}
|